# Maintainer: Austin Schaefer <schaefer.austin.p@inbox.eu>
pkgname=doubleo7-git
pkgver=0.2.0.r59.g8d7f8b6
pkgrel=1
pkgdesc="Local-first, multi-agent deep-research CLI"
arch=('x86_64')
url="https://code.austinschaefer.com/schaefera/doubleo7"
license=('custom')
depends=('gcc-libs')
makedepends=('cargo' 'git' 'cmake')
provides=('doubleo7')
conflicts=('doubleo7')
source=("$pkgname::git+ssh://git@51.15.208.55:22222/schaefera/doubleo7.git")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  local base
  base=$(grep -m1 '^version' Cargo.toml | cut -d '"' -f2)
  printf "%s.r%s.g%s" "$base" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$pkgname"
  cargo fetch --locked
}

build() {
  cd "$pkgname"
  export RUSTUP_TOOLCHAIN=stable
  # Distro CFLAGS/LDFLAGS hardening flags corrupt aws-lc-sys's vendored C
  # build (symbol-prefix mismatch at link time); build it with cc-rs's own
  # defaults instead.
  unset CFLAGS CXXFLAGS LDFLAGS CPPFLAGS
  cargo build --frozen --release
}

check() {
  cd "$pkgname"
  cargo test --frozen --release
}

package() {
  cd "$pkgname"
  install -Dm755 "target/release/doubleo7" "$pkgdir/usr/bin/doubleo7"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
}